Dynamische Array-Funktion SEQUENZ in Excel

Fortlaufende Zahlen in Excel mit dynamischer Array-Funktion erzeugen

Die Eingabe fortlaufender Zahlen in Excel können Sie sich bisher schon ersparen, indem Sie das Ausfüllkästchen am rechten unteren Rand einer Zelle anklicken und mit der Maus nach unten, oben, links oder rechts ziehen, um eine Datenreihe auszufüllen. Mit der neuen dynamischen Arrayfunktion SEQUENZ können Sie Datenreihen in Zukunft noch einfacher und komfortabler erzeugen.

Einfache Zahlenreihe

Mit der folgenden Formel in der Zelle A2 können Sie schnell eine Zahlenreihe erzeugen, die mit 1 beginnt und bei 10 endet:

=SEQUENZ(10)

Zahlenreihe mit Schrittweite 1 erstellen

Wie bei alle dynamischen Arrayfunktionen wird ein sogenannter Überlaufbereich erzeugt, den Sie am blau umrandeten Zellbereich erkennen können. Nähere Informationen zum Überlaufbereich finden Sie hier.

Wenn Sie statt einer Datenreihe mit 10 Zahlen eine mit 20 Zahlen benötigen, brauchen Sie nur die Formel in Zelle A2 entsprechend ändern.

Funktionsassistent SEQUENZ

Der Funktionsassistent für die Funktion SEQUENZ sieht so aus:

Funktionsassistent SEQUENZ

Die Funktion SEQUENZ kennt 4 Parameter, wobei nur der erste Parameter Zeilen angegeben werden muss. Mit den anderen Parametern können Sie steuern, ob Sie die Zahlenreihe statt in einer oder mehreren Spalten, mit einem anderen Anfangswert und einer anderen Schrittweite definieren wollen.

Datenreihe mit einem Anfangswert und einer Schrittweite ungleich 1 erzeugen

Die Formel für die Erzeugung einer Datenreihe mit 10 Zahlen, die mit 100 beginnt und eine Schrittweite von 10 aufweist, sieht folgendermaßen aus:

=SEQUENZ(10;1;100;10)

Zahlenreihe mit Anfangswert und Schrittweite erstellen

Kalender erzeugen

Mit der Funktion SEQUENZ können Sie eine Datenreihe mit allen Datumsangaben eines Kalenderjahres erzeugen. Die Formel in Zelle A2 für das Kalenderjahr 2019 mit 365 Tagen sieht so aus:

=SEQUENZ(365;1;DATUM(2019;1;1);1)

Den Zellen der erzeugten Zahlenreihe wird das Datumsformat nicht automatisch zugewiesen. Sie müssen die Zellen noch entsprechend formatieren.

Datenreihe mit Uhrzeiten erzeugen

Mit der folgenden Formel erzeugen Sie ausgehend von 00:00 Uhr eine Datenreihe mit den 96 Viertelstundenwerten eines Tages, wie Sie z.B. für die Leistungsmessung in der Energiewirtschaft verwendet wird:

=SEQUENZ(96;1;ZEIT(0;0;0);1/96)

Nachdem Sie alle Zellen im erzeugten Überlaufbereich mit dem Uhrzeitformat hh:mm versehen haben, sieht das Tabellenblatt so aus:

Uhrzeiten mit der Funktion SEQUENZ erzeugen

Die Schrittweite beträgt hier 1/96, weil in Excel Uhrzeiten eines Tages als Dezimalstellen dargestellt werden und ein Tag 24*12=96 Viertelstunden hat. Wenn Sie eine Zahlenreihe mit Halbstundenwerten erzeugen möchten, wählen Sie als Schrittweite den Wert 1/48, bei Stundenwerten den Wert 1/24.

Datenreihe mit Monatsnamen erzeugen

Wenn Sie die Funktion SEQUENZ in andere Funktionen einbetten, ergeben sich interessante Anwendungsmöglichkeiten. Im folgenden Beispiel werden die Monatsnamen eines Jahres in einer Spalte aufgelistet:

Monatsnamen mit der Funktion SEQUENZ erzeugen

In der Zelle A2 wurde die folgende Formel verwendet:

=TEXT(DATUM(JAHR(HEUTE());SEQUENZ(12;1);1);”MMMM”)

Die Funktion SEQUENZ dient in diesem Beispiel dazu, eine Zahlenreihe von 1 bis 12 für die 12 Monate des Jahres in 12 Zeilen und einer Spalte zu definieren. Sollen die Monatsnamen in einer Zeile und 12 Spalten erscheinen, lautet die Formel:

=TEXT(DATUM(JAHR(HEUTE());SEQUENZ(1;12);1);”MMMM”)

Größte Werte mit KGRÖSSTE und SEQUENZ ermitteln    

Wenn Sie die Funktion SEQUENZ in Kombination mit der Funktion KGRÖSSTE verwenden, können Sie beispielsweise aus einer Tabelle mit Bestellungen die größten Umsatzwerte oder die zeitlich letzten Bestellungen abrufen, wie das folgende Beispiel zeigt:

Funktionen SEQUENZ und KGRÖSSTE

In der Zelle F2 steht die folgende Formel:

=KGRÖSSTE(Bestellungen[Umsatz];SEQUENZ(F1))

Aus der Tabelle mit der Bezeichnung Bestellungen werden die größten Umsatzwerte aus der Spalte Umsatz ermittelt. Die Anzahl der Werte wird aus der Zelle F1 entnommen.

Die letzten 3 Bestellungen ermitteln Sie mit der folgenden Formel in Zelle F9:

=KGRÖSSTE(Bestellungen[Bestelldatum];SEQUENZ(F8))

Die ermittelten Zellwerte wurden abschließend noch mit dem Datumsformat versehen.

Die dynamische Arrayfunktion SEQUENZ ist nur verfügbar, wenn Excel über eine Office 365 Abonnement erworben wurde.

Ohne die dynamische Arrayfunktion SEQUENZ können Sie die letzten 3 Bestellungen auf die folgende Weise ermitteln:

  1. Geben Sie in der Zelle F9 folgende Formel ein:

    =KGRÖSSTE(Bestellungen[Bestelldatum];ZEILE()+1-ZEILE($F$9))
  2. Formatieren Sie die Zelle mit dem Datumsformat.
  3. Kopieren Sie die Formel in die Zellen F10 und F11.

Wenn Sie die Anzahl der letzten Bestellungen erhöhen oder verringern möchten, brauchen Sie bei der Verwendung der Funktion SEQUENZ nur den Wert in der Zelle F8 zu ändern. Bei der anderen Formel ist dies nur zu erreichen, indem Sie den Ausfüllbereich vergrößern oder verkleinern.

SVERWEIS mit SEQUENZ kombinieren

In dem folgenden Beispiel sollen per SVERWEIS pro Artikelnummer mehrere Informationen aus einer Artikelliste abgerufen werden. Der Zellbereich mit den Artikeldaten hat den Namen Artikeltabelle. In Kombination mit der Funktion SEQUENZ brauchen Sie die Formel mit dem SVERWEIS nur einmal eingeben, um die Bezeichnung, den Preis und den Speicher abzurufen.

Funktion SEQUENZ und SVERWEIS

Die Formel in Zelle G2 lautet:

=SVERWEIS(F2;Artikeltabelle;SEQUENZ(1;3;2;1);FALSCH)

Die Funktion SEQUENZ wird für das Argument Spaltenindex der Funktion SVERWEIS eingesetzt. Es soll eine Zahlenreihe in einer Zeile und drei Spalten beginnend mit dem Wert bzw. Spaltenindex 2 und der Schrittweite 1 gebildet werden.

Sie können diese Formel aus Zelle G2 per Ausfüllkästchen für andere Artikelnummer nach unten kopieren.

Michael Richter

Michael Richter

Autor

Ich unterstütze unsere Kunden in erster Linie durch Programmierung von Datenbankanwendungen und Zusatzmodulen von Microsoft Office. In Seminaren und Tipps auf unserer Blogseite gebe ich mein Wissen weiter.

0 Kommentare

Einen Kommentar abschicken

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert

Pin It on Pinterest

Share This