Mit Bedingungen in Excel rechnen

Falls mehrere Bedingungen in Excel geprüft werden sollen, werden oft mehrere WENN-Funktionen ineinander verschachtelt. Werden zu viele Bedingungen ineinander verschachtelt, sind die WENN-Bedingungen schlecht zu lesen sowie aufwändig zu ändern und zu prüfen. Es gibt eine ganze Reihe von Funktionen, die den Einsatz mehrerer Bedingungen in Excel übersichtlicher machen.

Mehrere Bedingungen in Excel – Alternativen zur WENN-Funktion

In dem folgenden Beispiel sollen unterschiedliche Funktionen gegenübergestellt werden, mit denen Sie Bedingungen in Excel prüfen können:
Zu mehreren Autoländerkennzeichen soll das jeweilige Land ermittelt werden.
Das Tabellenblatt sieht folgendermaßen aus:

Autoländerkennzeichen in Excel

Bedingungen in Excel mit der Funktion WENN

Beim Einsatz der WENN-Funktion sieht die Formel in Zelle B2 folgendermaßen aus:
=WENN(A2=”D”;”Deutschland”;WENN(A2=”NL”;”Niederlande”;WENN(A2=”A”;”Österreich”;WENN(A2=”CH”;”Schweiz”;””))))

Bedingungen in Excel mit der Funktion WENNS

Anwender, die Excel 365, Excel 2019 oder Excel 2016 einsetzen, können die WENNS-Funktion nutzen. Sie macht in diesem Anwendungsfall das Rechnen mit Bedingungen in Excel kürzer und die Formel leichter lesbar:
=WENNS(A2=”D”;”Deutschland”;A2=”NL”;”Niederlande”;A2=”A”;”Österreich”;A2=”CH”;”Schweiz”;WAHR;””)
Die WENNS-Funktion prüft die Bedingungen von links nach rechts. Es wird der Wert genommen, der bei der ersten erfüllten Bedingung eingetragen wurde. Trifft keine der Bedingungen zu, können Sie am Ende der Formel einen Standardwert definieren, in dem Sie als vorletztes Argument WAHR eingeben und als letztes Argument den Standardwert selbst. In unserem Beispiel wird der Text ausgegeben, wenn in der Spalte ein Länderkennzeichen eingetragen wurde, das von der WENNS-Funktion vorher nicht gefunden wurde.

Bedingungen in Excel mit der Funktion ERSTERWERT

Diese Funktion können ebenfalls nur Anwender verwenden, die mindestens die Version Excel 2016 einsetzen.
Die Formel lautet für Zelle B2:
=ERSTERWERT(A2;”D”;”Deutschland”;”NL”;”Niederlande”;”A”;”Österreich”;”CH”;”Schweiz;””)
Diese Funktion ist noch kürzer, da die Zelle A2, die geprüft wird, nur einmal angegeben wird. Diese Funktion arbeitet nach dem gleichen Prinzip wie die WENNS-Funktion. Das Formelergebnis hängt von der ersten erfüllten Bedingung ab. Wenn keine der angegebenen Bedingungen erfüllt ist, können Sie am Ende der Formel als letztes Argument einen Standardwert definieren. In unserem Fall ist es der Ausdruck . Wenn Sie auf den Standardwert verzichten und keine der Bedingungen zutrifft, erscheint in der Formelzelle der Fehlerwert #NV.
In allen drei Fällen sieht das Tabellenblatt mit den Ergebnissen so aus:

Autoländerkennzeichen mit Excel-Funktion ERSTERWERT

Bedingungen in Excel mit der Funktion SVERWEIS

Eine weitere Möglichkeit mit Bedingungen in Excel zu rechnen und ineinander geschachtelte WENN-Bedingungen zu vermeiden, ist in diesem Fall der klassische SVERWEIS. Er hat den Vorteil, dass die Liste mit den Länderkennzeichen beliebig erweitert werden kann. Um das Land zu einem Autoländerkennzeichen zu ermitteln, gehen Sie bitte folgendermaßen vor:

  1. Erstellen Sie in Spalte A und B die folgende Liste und geben Sie dem Zellbereich A11:B14 den Namen Länderkennzeichen.

    Autoländerkennzeichen mit SVERWEIS

  2. Geben Sie in der Zelle B2 folgende Formel ein:

=WENNFEHLER(SVERWEIS(A2;Länderkennzeichen;2;FALSCH);””)

Das Tabellenblatt sieht folgendermaßen aus:

Autoländerkennzeichen mit SVERWEIS

Wird ein Autoländerkennzeichen in der Tabelle nicht gefunden, sorgt die Funktion WENNFEHLER dafür, dass anstelle des Fehlerwertes #NV der Ausdruck als Formelergebnis ausgegeben wird. Achten Sie bei der Funktion SVERWEIS darauf, dass Sie als vierten Parameter den Ausdruck FALSCH eingeben, damit in der Liste nach einer genauen Übereinstimmung gesucht wird.


Bedingungen in Excel mit Funktion WAHL

Die Funktion WAHL erlaubt Berechnungen mit Bedingungen in Excel, wenn der Wert eines Ausdrucks 1, 2, 3 usw. beträgt. Diese Funktion kann ebenfalls die WENN-Funktion ersetzen. Im folgenden Beispiel dient die Funktion dazu, eine Beschreibung für Filmbewertungen auszugeben:
Das Tabellenblatt sieht folgendermaßen aus:

Autoländerkennzeichen mit Excel-Funktion WAHL

Die Formel in Zelle C2 lautet:
=WAHL(LÄNGE(B2);”schlecht”;”uninteressant”;”ok”;”gut”;”sehr gut”)
Mit dieser Formel wird zunächst die Funktion LÄNGE verwendet, um die Anzahl der Sterne in der Zelle B2 zu ermitteln: Die WAHL-Funktion arbeitet folgendermaßen:
Wenn in der Zelle nur ein Stern erscheint, wird der Film als schlecht bewertet. Bei zwei Sternen ist das Ergebnis uninteressant usw. Allgemein arbeitet die Funktion nach dem folgenden Prinzip:
=WAHL(zu prüfender Ausdruck;Ausdruck wenn Wert=1; Ausdruck wenn Wert=2; Ausdruck wenn Wert=3;…)
Sollte kein Stern in der Zelle stehen, wird der Fehlerwert #WERT ausgegeben. Diesen Fehlerwert können Sie vermeiden, indem Sie die Funktion WAHL in die Funktion WENNFEHLER einbetten:

=WENNFEHLER(WAHL(LÄNGE(B2);”schlecht”;”uninteressant”;”ok”;”gut”;”sehr gut”);”ohne Bewertung”)

Hinweise

  • Die Funktion ERSTERWERT kann bis zu 126 Fälle unterscheiden. In der englischsprachigen Version heißt die Funktion SWITCH. Sie können mit dieser Funktion nur genaue Übereinstimmungen prüfen. Operatoren wie > oder < sind nicht möglich.
  • Die Funktion WENNS kann bis zu 127 Bedingungen prüfen. Im Vergleich dazu: Sie können maximal 64 WENN-Bedingungen ineinander verschachteln.
Michael Richter

Michael Richter

Autor

Ich unterstütze unsere Kunden in erster Linie durch Programmierung von Datenbankanwendungen und Zusatzmodulen von Microsoft Office. In Seminaren und Tipps auf unserer Blogseite gebe ich mein Wissen weiter.

11 Kommentare

  1. Ich benötige eine Formel.
    Wert (E8) unter/bis 100 E10) = 115€
    Wert zwischen 100 und 200 (E11) = 230€
    Wert zwischen 200 und 300 (E12) = 345€
    Wert zwischen 300 und 400 (E13) = 460€
    können sie mir helfen?
    Viele Grüße

    Antworten
    • Hallo,
      das ist eine Aufgabe für einen SVERWEIS.

      Antworten
  2. Datum Name Uhrzeit N.-Std. Honorar
    40,00 €
    01.01.2023 KH Arzt 07:00 15:30 8,5 340,00 €
    01.01.2023 KH Arzt 15:30 07:00 15,5 620,00 €
    02.01.2023 Dr. Beate Hahn 07:00 15:30
    02.01.2023 KH Arzt 15:30 07:00 15,5 620,00 €
    03.01.2023 Dr. Beate Hahn 07:00 15:30
    03.01.2023 KH Arzt 15:30 07:00 15,5 620,00 €
    04.01.2023 Dr. Carsten Pietsch 07:00 15:30
    In der Spalte Honorar soll er mir die Anzahl zusammen rechnen (4), aber das Datum beachten und nicht doppelt zählen. Gewünschtes Ergebniss = 3. Ich bekomme es hin, dass er das Datum einzelnd zählt (=SUMMENPRODUKT((ZÄHLENWENN($B$7:$B$68;$B$7:$B$68)=2)/2)), auch die Anzahl (=ANZAHL(G7:G68)), aber nicht beides kombiniert.
    Kann mir jemand helfen?

    Antworten
    • Ich würde die Auswertung in einer Pivot Tabelle vornehmen:

      in Zeilen: Datum Name
      Werte: Anzahl von Honorar

      Antworten
  3. Hallo Herr Richter,

    ich möchte gerne 3 WENN Bedingungen einfügen.
    Beispiel:

    =WENN(E3>=(1500000*0,03);”A”;WENN(E3<(1500000*0,03);"B";WENN(E3<(1500000*0,01);"C";)))

    Leider wird bei dieser Formel "C" nicht mit beachtet. Können Sie mir weiterhelfen?
    Danke

    Mit freundlichen Grüßen

    Stefan Kaiser

    Antworten
    • Guten Tag Herr Kaiser,

      ändern Sie wie Formel wie folgt:
      =WENN(E3>=(1500000*0,03);“A“;WENN(E3<(1500000*0,01);"C";WENN(E3<(1500000*0,03);"B";)))

      Antworten
  4. Danke, der Hinweis mit WENNS (für gleich, besser, schlechter) ist perfekt!

    Antworten
  5. Angenommen ich habe eine Variable, die die Dauer in Stunden und Minuten angibt, beispielsweise zweieinhalb Stunden so: 02:30. Jetzt will ich eine neue Variable erstellen, die die Dauer in Intervalle teilt. Also, wenn die Dauer größer als 0 Stunden aber kleiner oder gleich 2 Stunden ist, möchete ich die Kodierung 1 vergeben, wenn sie größer als 2 Stunden, aber kleiner oder gleich 4 Stunden ist, soll die Kodierung 2 sein usw. Das Ganze bis zu dem Intervall größer als 18 Stunden aber kleiner oder gleich 20 Stunden.

    Natürlich kann ich jetzt WENN-Funktionen ineinander verschachteln. Das sind aber sehr viele WENN-Funktionen. Ich frage mich, ob das nicht einfacher geht. Ginge das mit WENNS und wenn ja, wie? Über eine Antwort würde ich mich freuen.

    Antworten
    • Ich habe gerade selbst eine Möglichkeit gefunden. Mit SVERWEIS geht das ganz einfach. Auf einem anderen Arbeitsblatt habe ich eine Definitionstabelle für die Intervalle erstellt, mit den Spalten »Untergrenze«, »Obergrenze« und »Kodierung«. Wenn in Spalte F der Datenmatrix die Variable »Dauer« steht dann sieht die Formel für die Umkodierung in der Zeile für den ersten Datensatz (Zeile 2) so aus:

      =SVERWEIS(F2;$Kodierung.$G$3:$I$12;3;1)

      Dabei ist »Kodierung« die Bezeichnung des Arbeitsblattes, in dem die Definiitionstabelle für die Intervalle steht. Der Bereich G3:I12 ist die Definitionstabelle selbst. Die Kodierungen für die neue Variable stehen in Spalte 3 dieser Tabelle. Eine Ausgabe soll erfolgen, wenn die jeweilige Bedingung wahr ist (das ist die 1 ganz am Ende). Jedenfalls habe ich das so verstanden.

      Viele Grüße!

      Antworten
  6. Hallo Herr Richter,

    vielen Dank für Ihren Beitrag. Wenn ich die oben genannten kopierte Formeln einsetzte, erscheint immer die gleiche Fehlermeldung, bei allen Varianten:

    #NAME?

    Was mache ich falsch?

    Vielen Dank im Voraus

    Antworten
    • Hallo Herr Hütte,

      de Fehlerwert #Name? erscheint, wenn ein Zellbereichsname, den Sie in einer Formel verwenden, nicht existiert, oder wenn ein Funktionsname unbekannt ist. Setzen Sie eventuell eine Excel-Version ein, die die Funktionen SUMMEWENNS oder WAHL nicht kennt?

      Antworten

Einen Kommentar abschicken

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert

Pin It on Pinterest

Share This