Bei der Analyse von Bewertungen von Produkten und Dienstleistungen sind neben den statistischen Größen Summe, Mittelwert, Minimum und Maximum oft auch die Häufigkeiten der Nennungen wichtig. In unserem Beispiel erfahren Sie, wie Sie die Häufigkeit von Zahlen und Wörtern ermitteln können.

Häufigkeiten von Zahlen berechnen

Ausgangsbeispiel

In der folgenden Tabelle finden Sie die Punktbewertungen von 3 Produkten auf einer Webseite für einen bestimmten Zeitraum. Die Besucher der Webseite können zwischen einem für eine schlechte und fünf Punkten für eine sehr gute Bewertung des Produktes vergeben. Die Tabelle mit den Namen Bewertungen sieht folgendermaßen aus:

Tabelle mit Punktzahlen als Bewertung

Häufigkeit von allen Punktzahlen ermitteln

Zunächst soll für jede Punktzahl die Anzahl der Nennungen ermittelt werden. Für diese Berechnung können Sie die Funktion HÄUFIGKEIT verwenden. Gehen Sie dabei folgendermaßen vor:

1. Erstellen Sie ab der Zelle E2 eine auf- oder absteigende Liste aller zu vergebenen Punktzahlen.
2. Geben Sie in der Zelle F2 die folgende Formel für die Berechnung der Häufigkeiten an:=HÄUFIGKEIT(Bewertungen[Punkte];E2:E7)

Wenn Sie Excel in einer Version vor Excel 2021 einsetzen, müssen Sie die eingegebene Formel mit der Tastenkombination STRG+ALT+RETURN abschließen, weil es sich um eine Matrixformel handelt. In den neueren Versionen von Excel wird automatisch ein Überlaufbereich erzeugt mit der Anzahl der Nennungen pro Punktzahl. Dieser Überlaubereich umfasst mehr als eine Zelle als die Anzahl der Punktzahlen. In der letzten Zelle wird bei einer aufsteigenden Liste der Punktzahlen die Anzahl der Nennungen angezeigt, in denen die vergebene Punktzahl größer als 5 ist.

Das Ergebnis im Tabellenblatt sieht so aus:

Funktion HÄUFIGKEIT

Berechnung der am häufigsten genannten Punktzahl

Die am häufigsten genannte Punktzahl ermitteln Sie mit der folgenden Formel:

= MODUS.EINF(Bewertungen[Punkte])

Das Ergebnis lautet: Punktzahl 3

Die Funktion MODUS.EINF berechnet die am häufigsten vorkommende Zahl in einem Zellbereich. Das EINF steht für einfach. Wenn es zwei oder mehrere verschiedene Zahlen gibt, die gleich oft am häufigsten vorkommen, zeigt diese Funktion nur die erste Zahl ein. Die Punktzahl 4 wurde ebenfalls 10-mal vergeben. Sie erscheint nicht in der Ergebniszelle.

Mit der Funktion MODUS.VIELF werden alle Zahlen ermittelt, die mehrmals am häufigsten vorkommen. Die Formel lautet:

=MODUS.VIELF(Bewertungen[Punkte])

Diese Formel erzeugt ab der Version Excel 2021 einen Überlaufbereich. Im Tabellenblatt sieht es so aus:

Funktion MODUS.VIELF

Berechnung der am häufigsten genannten Punktzahl für jedes Produkt

Im nächsten Schritt möchten Sie für jedes der drei Produkte wissen, welche Punktzahl am häufigsten vergeben wurde.

Wenn das Produkt 1 in Zelle E2 steht, sieht die Formel so aus:

=MODUS.EINF(WENN(Bewertungen[Produkt]=E2;Bewertungen[Punkte]))

Kopieren Sie die Formel nach unten, um die Werte für die beiden anderen Produkte zu ermitteln.

Funktion MODUS.EINF mit Funktion WENN

Häufigkeiten von Wörtern berechnen

Ausgangsbeispiel

Die Tabelle mit den Bewertungen enthält in diesem Fall keine Punktzahlen, sondern Benotungen für die Qualität der drei Produkte. Die Benotungen reichen von sehr gut bis schlecht. Die Tabelle mit dem Namen Bestellungen2 sieht so aus:

Tabelle mit Text als Bewertung

Häufigkeit von allen Benotungen ermitteln

Wenn Sie alle möglichen Bewertungen in einem Zellbereich angeben, ermitteln Sie mit der folgenden Formel die Häufigkeit für jede einzelne Bewertung:

=ZÄHLENWENN(Bewertungen2[Bewertung];E10)

Wenn Sie die Formel für alle Bewertungen nach unten kopieren, sieht das Ergebnis im Tabellenblatt so aus:

Funktion ZÄHLENWENN

Ermittlung der häufigsten vorkommenden Benotung

Die Formel für die Berechnung der am häufigsten vorkommende Benotung sieht so aus:

=INDEX(Bewertungen2[Bewertung];VERGLEICH(MAX(ZÄHLENWENNS(Bewertungen2[Bewertung];Bewertungen2[Bewertung]));ZÄHLENWENNS(Bewertungen2[Bewertung];Bewertungen2[Bewertung]);0))

Erläuterung der Formel:

Zunächst wird mit dem Ausdruck ZÄHLENWENNS(Bewertungen2[Bewertung];Bewertungen2[Bewertung]) für jede Zelle in der Spalte Bewertung die Anzahl der Benotungen für den in der Zelle stehenden Text ermittelt. Das Array sieht so aus: {10;10;4;10;..;10;10}

Dann wird mit der Funktion MAX der höchste Wert aus dem Array berechnet. Es ist der Wert 10. Mit der Funktion VERGLEICH wird danach in der Spalte Bewertung die Position des ersten maximalen Werts ermittelt. Die Funktion INDEX wird verwendet, um aus der Spalte Bewertung den Eintrag in der Zelle mit dem ersten maximalen Wert zu bestimmen. Das ist in unserem Beispiel die erste Zelle mit der Position 1 und der Bewertung gut.

Wenn Sie eine Excel-Version nutzen, die die Funktion LET kennt, können Sie auch die folgende Formel nutzen:

=LET(Anzahl_Wörter;ZÄHLENWENNS(Bewertungen2[Bewertung];Bewertungen2[Bewertung]);INDEX(Bewertungen2[Bewertung];VERGLEICH(MAX(Anzahl_Wörter);Anzahl_Wörter;0)))

Da die Formel ZÄHLENWENNS(Bewertungen2[Bewertung];Bewertungen2[Bewertung]) zweimal in der ersten Formel vorkommt, können Sie diesem Formelteil einen Namen geben und ihn in der weiteren Formel verwenden. Der Name für den Formelteil lautet Anzahl_Wörter.

Wenn Sie nicht ausschließen können oder wollen, dass es zwei oder mehrere Benotungen gibt, die am meisten genannt wurden, verwenden Sie besser die folgende Formel:

=LET(Anzahl_Wörter;ZÄHLENWENNS(Bewertungen2[Bewertung];Bewertungen2[Bewertung]);SORTIEREN(EINDEUTIG(FILTER(Bewertungen2[Bewertung];Anzahl_Wörter=MAX(Anzahl_Wörter)))))

Mit dieser Formel wird die Spalte Bewertung gefiltert. Das Kriterium lautet: In welchen Zeilen stehen Benotungen, in denen die maximale Anzahl von Benotungen vorkommt? Mit der Funktion EINDEUTIG wird sichergestellt, dass jede Benotung nur einmal erscheint. Abschließend wird diese Liste der am häufigsten vorkommenden Benotungen mit der Funktion SORTIEREN aufsteigend sortiert.

Das Ergebnis der Formel sieht so aus, wenn es zwei Produkte gibt, deren Bewertung beide gleich oft und am häufigsten angegeben wurden:

Mehrere häufigste Texte

Fazit

Mit den Excel-Funktionen MODUS.INF und MODUS.VIELF ermitteln Sie die Zahlen, die am häufigsten in einem Zellbereich vorkommen. Wenn Sie wissen möchten, welche Texte in einem Zellbereich am häufigsten erscheinen, ist eine Formel mit einer Kombination der Funktionen ZÄHLENWENN, MAX, EINDEUTIG und FILTER dafür gut einsetzbar.