Vorteile der neuen Excel-Funktion LET

Abonnenten von Microsoft 365 steht seit kurzem in Excel die neue Funktion LET zur Verfügung. Sie können diese Funktion einsetzen, um Formeln schneller und leichter zu verstehen. Kompliziertere Formeln können Sie auf diese Weise übersichtlicher gestalten. Im folgenden Tipp stellen wir Ihnen diese neue Funktion mit einigen Beispielen vor.

Vorteile

Sie erhöhen die Lesbarkeit insbesondere von längeren Formeln dadurch, dass Sie mit der Funktion LET einzelnen Werten oder Berechnungsergebnissen Namen zuweisen. Diese Namen gelten nur im Rahmen der Formel. Wenn Sie in der LET-Formel Namen vergeben, werden die Ergebnisse zwischengespeichert. Bei der Anwendung dieser Namen in der Formel wird auf die Zwischenergebnisse zurückgegriffen. Eine Neuberechnung ist nicht notwendig. Dadurch werden Formeln mit der LET-Funktion schneller berechnet.

Funktionsassistent

Wenn Sie nach der Eingabe von =LET in einer Zelle den Funktionsassistenten aufrufen, wird die Funktion so dargestellt:

Die Funktion erwartet mindestens drei Parameter. Als erster Parameter vergeben Sie einen Namen für einen Wert, einen Zellbezug oder einem Berechnungsergebnis: Dieser Name darf keinem Zellbezug entsprechen und muss mit einem Buchstaben beginnen. Anführungszeichen dürfen nicht eingeben werden. Leerzeichen im Namen sind nicht erlaubt.

Als zweiten Parameter können Sie einen konstanten Wert, einen Zellbezug oder eine Berechnung angeben. Im dritten Parameter geben Sie eine Formel ein, in dem Sie den als ersten Parameter vergebenen Namen verwenden können.

Mit der Funktion LET können Sie mehrere Namen vergeben. Namen und deren Zuordnungen werden als Parameter paarweise hintereinander eingegeben. Der letzte Parameter ist eine Berechnungsformel. Eine gültige LET-Formel hat demzufolge immer eine ungerade Anzahl von Parametern.

Wenn Sie die LET-Funktion ohne Funktionsassistenten verwenden, sieht sie so aus:

In der eingesetzten Excel-Version erscheinen die englischen Parameternamen.

Beispiel 1

Im erstem Beispiel soll der Bruttopreis einer Artikelposition ermittelt werden. Das Tabellenblatt sieht so aus:

Die Formel in Zelle D2 zur Ermittlung des Bruttopreises lautet:

=LET(Menge;A2;Einzelpreis;B2;MwSt;C2;Menge*Einzelpreis*(1+MwSt))

Die Mengenangabe in Zelle A2 hat den Namen Menge und die Preisangabe in Zelle B2 den Namen Preis bekommen. Als dritter Name wurde der Mehrwertsteuersatz in Zelle C2 verwendet. Er heißt MwSt. Als fünfter Parameter wurde die Formel zur Berechnung des Bruttopreises mit Verwendung der vorher definierten Namen eingesetzt.

Alternativ könne Sie mit der Funktion LET auch folgende Formel verwenden:

=LET(Nettopreis;A2*B2;MwSt;C2;Nettopreis*(1+MwSt))

Der Ausdruck A2*B2 wurde hier mit Nettopreis benannt und später in der Berechnungsformel eingesetzt.

Beispiel 2

Formeln mit der Funktion LET sind deutlich verständlicher, weil bestimmte Ausdrücke in der Formel nicht wiederholt werden müssen.

In diesem Beispiel soll aus einer Tabelle mit dem Namen Bestellungen für einen bestimmten Auftrag der Nettowert unter Berücksichtigung eines eventuellen Rabatts ermittelt werden. Ein Rabatt von 5% wird gewährt, wenn der Nettobetrag mindestens 100 € beträgt: Das Tabellenblatt sieht so aus:

Die Formel ohne LET sieht so aus:

=WENN(SUMMEWENN(Bestellungen[Auftrag];F5;Bestellungen[Positionswert])>G1;SUMMEWENN(Bestellungen[Auftrag];F5;Bestellungen[Positionswert])*(1-G2);SUMMEWENN(Bestellungen[Auftrag];F5;Bestellungen[Positionswert]))

In der obigen Formel erscheint der folgende Ausdruck dreimal:

SUMMEWENN(Bestellungen[Auftrag];F5;Bestellungen[Positionswert])

Die LET-Funktion verwendet diesen Ausdruck dagegen nur einmal. Die Formel zur Berechnung kann folgendermaßen gekürzt werden:

=LET(Nettowert;SUMMEWENN(Bestellungen[Auftrag];F5;Bestellungen[Positionswert]);Rabatt;WENN(Nettowert>G1;5%;0%);Nettowert*(1-Rabatt))

Die definierten Namen sind in der obigen Formel fett markiert worden. Der Ausdruck zur Bestimmung des Nettowertes ohne Rabatt wurde Nettowert benannt. Die Bestimmung des Rabattsatzes wurde Rabatt genannt. In der abschließenden Formel werden nur noch die vorher definieren Namen verwendet. Die Formel mit LET ist deutlich übersichtlicher als die Formel ohne LET.

Beispiel 3

Das dritte Beispiel zeigt Ihnen die Verwendung von LET im Zusammenspiel mit dynamischen Arrayfunktionen. Es soll eine Liste erzeugt werden, die in einem vorgegebenen Zeitraum alle Ultimos anzeigt.

Die Formel, die in Zelle A5 eingeben wurde, lautet so:

=LET(Datumsbereich;SEQUENZ(B2-B1+1;1;B1;1);FILTER(Datumsbereich;MONATSENDE(Datumsbereich;0)=Datumsbereich))

Zunächst wird mit der Funktion SEQUENZ ein Datumsbereich erzeugt. Der Start und das Ende des Zeitraums werden aus den Zellen B1 und B2 entnommen. Das Ergebnis ist eine einspaltige Tabelle mit allen Datumsangaben in diesem Zeitraum. Diese Berechnung wird der Name Datumsbereich gegeben. Dieser Datumsbereich wird mit der dynamischen Arrayfunktion FILTER auf die Zeilen reduziert, in der das jeweilige Datum dem Monatsende entspricht. Mit der Funktion MONATSENDE wird das Monatsende bezogen auf ein konkretes ermittelt.

Hinweise

  • Wenn Sie in der Arbeitsmappe bzw. in einem Tabellenblatt für eine Zelle oder Zellbereich einen Namen vergeben haben, den Sie auch in der Formel mit LET verwenden, hat der Name in der LET-Funktion Vorrang. Bei der Eingabe des Namens Menge in der Formel sieht das Intellisense-Fenster so aus:
  • Das Symbol links vom Namen kennzeichnet den Typ. Das Tabellensymbol weist auf einen Zellbereichsnamen hin, das Symbol mit dem x auf einen Namen in der aktuellen LET-Formel.
  • Der folgende Ausdruck ist eine gültige Formel:

    =LET(Menge;Menge;Menge*2)

    In diesem Fall wird dem Wert in der Zelle mit dem Namen Menge (zweiter Parameter) der Name Menge gegeben.

Einmal vergebene Namen können nicht nur in der Berechnungsformel angewendet werden, sondern bei der Vergabe weiterer Namen eingesetzt werden. Im folgenden Beispiel wurde der Name Nettopreis verwendet, um die Mehrwertsteuerbetrag zu ermitteln.:

=LET(Nettopreis;10;MwSt;Nettopreis*16%;Nettopreis+MwSt)

Das Ergebnis ist 11,6.

Michael Richter

Michael Richter

Autor

Ich unterstütze unsere Kunden in erster Linie durch Programmierung von Datenbankanwendungen und Zusatzmodulen von Microsoft Office. In Seminaren und Tipps auf unserer Blogseite gebe ich mein Wissen weiter.

0 Kommentare

Einen Kommentar abschicken

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert.

Pin It on Pinterest

Share This